PRINT GEN                                                              
         TITLE 'ALC$JOB - GET JOB NAME FOR REPORT HEADING USE'                  
*  REMARKS:  GET JOB NAME VIA EXTRACT MACRO                                     
*                                                                               
*  REGISTER USAGE                                                               
*       R8  = POINTER TO INPUT PARMS                                            
*       R9  = POINTER TO TASK IO AREA                                           
*       R10 = INTERNAL BRANCH REGISTER                                          
*       R11 = BASE REGISTER                                                     
*       R12 = BASE REGISTER                                                     
R0       EQU   0                                                                
R1       EQU   1                                                                
R2       EQU   2                                                                
R3       EQU   3                                                                
R4       EQU   4                                                                
R5       EQU   5                                                                
R6       EQU   6                                                                
R7       EQU   7                                                                
R8       EQU   8                                                                
R9       EQU   9                                                                
R10      EQU   10                                                               
R11      EQU   11                                                               
R12      EQU   12                                                               
R13      EQU   13                                                               
R14      EQU   14                                                               
R15      EQU   15                                                               
R00      EQU   0                                                                
R01      EQU   1                                                                
R02      EQU   2                                                                
R03      EQU   3                                                                
R04      EQU   4                                                                
R05      EQU   5                                                                
R06      EQU   6                                                                
R07      EQU   7                                                                
R08      EQU   8                                                                
R09      EQU   9                                                                
ALC$JOB CSECT                                                                   
         USING *,R11,R12               R11,R12=BASE REGISTERS                   
         STM   R14,R12,12(R13)         SAVE REGISTERS                           
         LR    R11,R15                 ADDRESSIBILITY                           
         LA    R12,2048(0,R11)                                                  
         LA    R12,2048(0,R12)                                                  
         LR    R1,R13                  SAVE SAVE AREA POINTER                   
         LA    R13,SAVEAREA            POINT TO MY SAVEAREA                     
         ST    R13,8(0,R1)             SET FORW CHAIN IN CALLERS SAREA          
         ST    R1,4(0,R13)             SET BACK CHAIN IN MY SAVEAREA            
         L     R1,24(0,R1)             REACQUIRE R1 AS IT CAME HERE             
         L     R8,0(R1)                POINT R8 TO INPUT PARMS                  
         USING OUTJOBX,R8                                                       
         B     START                                                            
         DS    0F                                                               
         DC    C'*'                                                             
PGMID    DC    CL8'ALC$JOB '                                                    
         DC    C'*'                                                             
COMPDATE DC    CL8'&SYSDATE'                                                    
COMPTIME DC    CL8'&SYSTIME'                                                    
SAVEAREA DC    18F'0'                                                           
START    EQU   *                                                                
         EXTRACT TIOTADDR,FIELDS=TIOT                                           
         L     R9,TIOTADDR             POINT TO TASK IO WORK AREA               
         USING TIOTMAP,R9              ADDRESSIBILITY                           
         MVC   OUTJOB,TIOCNJOB         MOVE JOB TO OUTPUT                       
$GOBACK  EQU   *                                                                
         L     R13,4(0,R13)            POINT BACK TO CALLERS SAVEAREA           
         LM    R14,R12,12(R13)         RESTORE REGISTERS                        
         XR    R15,R15                 CLEAR RETURN CODE                        
         BR    R14                     GOBACK TO MOMMA                          
         LTORG                                                                  
         EJECT                                                                  
         DS    0F                                                               
TIOTADDR DS    F             ADDR OF TASK IO AREA                               
         EJECT                                                                  
*  INPUT PARMS                                                                  
OUTJOBX  DSECT                                                                  
OUTJOB   DS    CL8                                                              
         SPACE 2                                                                
* MAP OF TASK IO AREA VIA EXTRACT FIELDS=TIOT MACRO                             
*                                                                               
TIOTMAP  DSECT                                                                  
TIOCNJOB DS    CL8             JOB NAME                                         
TIOCSTEP DS    CL16            STEP NAME                                        
         DS    CL40                                                             
         END   ALC$JOB